トップページ　≫　スクリプト　≫　コードサンプル　≫　E233系京浜東北線 LED順次表示（3パターン）

手順一覧

スクリプトをコピーするには...

サンプルの右上に表示される
下記のアイコンを左クリックすると
スクリプトだけが別窓で開くので、
右クリックメニューの［すべて選択］→［コピー］をしてください。

スクリプトを貼り付けるには...

スクリプトの編集ウィンドウにあるメニューで［編集］→［張り付け］をしてください。

わからない点がある場合は...

当ページの解説の中で
ご不明な点がありましたら、
お気軽に下記までご質問下さい。

1.完成予定図

このページのスクリプトサンプルを使用した場合のビュワー動画です。
どのようなことが出来るのか、はじめに映像でご確認ください。
（動画の細部が見え難い場合はYoutubeでHD画質を選択してみてください）

2.レイアウトを作成する

編成を1つ配置してください。
車両には、E233系通勤形電車（京浜東北線）の
「クハE232-1004」を入れておいてください。

3.リソースを登録する

はじめに、E233系京浜東北線のLEDは、
列車の速度と連動して様々な表示パターンを行ないます。

特徴的なのは、停車中の側面LEDが次駅を日本語と英語で表示したり、
一定の速度まで加速すると側面LEDが消灯したりします。

↓

この様々な表示を車輌テクスチャーにすると画像のようになります。

ワンポイント

停車中のテクスチャーが3枚ではなく6枚になっているのは、
前面LEDの2種類を交互に表示させつつ、
側面LEDの3種類を順次表示させるためです。

↓

下記のリンクから車両テクスチャー画像をダウンロードしてください。
(解凍すると、クハE232-1004用の車両テクスチャーが20枚入っています)

↓

編成エディターにある［リソース編集］を左クリックしてください。

↓

リソースの編集ウィンドウが開くので［追加］を左クリックしてください。

↓

ファイルを選択するウィンドウが開きます。
ダウンロードした「E233系_蒲田_停車_1号車_001.png」を選択して、
［OK］を左クリックしてください。

↓

これで1枚目の車輌テクスチャー画像を登録できました。

↓

同様の手順で残りの画像をすべて登録していってください。

ワンポイント

「蒲田」行きの画像をファイル名の末尾の順で10枚登録した後に、
「大宮」行きの画像をファイル名の末尾の順で10枚登録してください。

4.スクリプトを記述する

■ 編成用スクリプト　［非表示］
図のように編成へスクリプトを記述します。
下記の編成スクリプトをコピーして貼り付けてください。

▼ 編成スクリプト

										//-----リソースの初期設定▼--
										SelectTrainResource 1
										//-----リソースの初期設定▲--

										//-キーボードイベント登録▼--
										Var リソース
										SetEventKey this 行先制御 リソース z
										//-キーボードイベント登録▲--

										//---------各メソッド定義▼--
										BeginFunc 行先制御
										 CallCar 行き先変更
										EndFunc

										BeginFunc 速度監視
										 Var 走行速度
										 GetCurrentSpeed	走行速度

										 ifzero 走行速度
										  CallCar 停車判定
										 endif

										 if> 走行速度 0
										  if>= 走行速度 50
										   CallCar 高速判定
										  else
										   CallCar 走行判定
										  endif
										 endif
										EndFunc
										//---------各メソッド定義▲--
■ 車輌用スクリプト　［表示］
図のように車両「クハE232-1004」へスクリプトを記述します。
下記の車両スクリプトをコピーして貼り付けてください。

▼ 車両スクリプト

										//---------------設定項目▼--
										Var 高速・初期開始ID
										set 高速・初期開始ID 1
										Var 高速・初期終了ID
										set 高速・初期終了ID 2

										Var 走行・初期開始ID
										set 走行・初期開始ID 3
										Var 走行・初期終了ID
										set 走行・初期終了ID 4

										Var 停車・初期開始ID
										set 停車・初期開始ID 5
										Var 停車・初期終了ID
										set 停車・初期終了ID 10

										Var パターン数
										set パターン数 10

										Var 行き先数
										set 行き先数 2

										Var 切替間隔
										set 切替間隔 3
										//---------------設定項目▲--

										//---------変数の初期設定▼--
										mul 切替間隔 1000

										Var 速度対応表示
										set 速度対応表示 0

										Var 変更回数
										set 変更回数 1

										Var 高速・開始ID
										mov 高速・開始ID 高速・初期開始ID

										Var 高速・終了ID
										mov 高速・終了ID 高速・初期終了ID

										Var 走行・開始ID
										mov 走行・開始ID 走行・初期開始ID

										Var 走行・終了ID
										mov 走行・終了ID 走行・初期終了ID

										Var 停車・開始ID
										mov 停車・開始ID 停車・初期開始ID

										Var 停車・終了ID
										mov 停車・終了ID 停車・初期終了ID

										Var 現行表示ID
										set 現行表示ID 高速・開始ID
										//---------変数の初期設定▲--

										//---タイマーイベント登録▼--
										Var 交互表示
										SetEventTimer this 方向幕制御 交互表示 切替間隔
										//---タイマーイベント登録▲--

										//---------各メソッド定義▼--
										BeginFunc 方向幕制御
										  Var TRN
										  getparent	TRN
										  call TRN 速度監視
										  add 現行表示ID 1

										 ifeq 速度対応表示 1
										  if> 現行表示ID 停車・終了ID
										   mov 現行表示ID 停車・開始ID
										  endif
										 endif

										 ifeq 速度対応表示 2
										  if> 現行表示ID 走行・終了ID
										   mov 現行表示ID 走行・開始ID
										  endif
										 endif

										 ifeq 速度対応表示 3
										  if> 現行表示ID 高速・終了ID
										   mov 現行表示ID 高速・開始ID
										  endif
										 endif

										 SetSignTexture 現行表示ID
										EndFunc

										BeginFunc 行き先変更
										 set 速度対応表示 0
										 add 変更回数 1

										 if> 変更回数 行き先数
										  set 変更回数 1
										  mov 高速・開始ID 高速・初期開始ID
										  mov 高速・終了ID 高速・初期終了ID

										  mov 走行・開始ID 走行・初期開始ID
										  mov 走行・終了ID 走行・初期終了ID

										  mov 停車・開始ID 停車・初期開始ID
										  mov 停車・終了ID 停車・初期終了ID
										 else
										  add 高速・開始ID パターン数
										  add 高速・終了ID パターン数

										  add 走行・開始ID パターン数
										  add 走行・終了ID パターン数

										  add 停車・開始ID パターン数
										  add 停車・終了ID パターン数
										 endif
										EndFunc

										BeginFunc 停車判定
										 ifeq 速度対応表示 1
										 else
										  mov 現行表示ID 停車・開始ID
										 endif
										 set 速度対応表示 1
										EndFunc

										BeginFunc 走行判定
										 ifeq 速度対応表示 2
										 else
										  mov 現行表示ID 走行・開始ID
										 endif
										 set 速度対応表示 2
										EndFunc

										BeginFunc 高速判定
										 ifeq 速度対応表示 3
										 else
										  mov 現行表示ID 高速・開始ID
										 endif
										 set 速度対応表示 3
										EndFunc
										//---------各メソッド定義▲--

4.ビュワーで動作確認する

お疲れ様でした、以上でスクリプトの設定は完了です。
ビュワーを起動して、LEDの動作を確認してください。

停車中は次駅などの情報を3パターンで順次表示します。
走行中（50km/h以下）には2パターンの交互表示に切り替わり、
高速走行（50km/h以上）まで加速すると側面LEDは消灯します。
キーボードの［Z］を押すと「大宮」→「蒲田」の順で切り替わります。

もし、ビュワーが起動できない場合や、
ご自身のレイアウトに合わせて改造したい場合など、
ご不明な点やご質問がありましたら、下記までお気軽にご連絡ください。

6.他の車両にも組み込むには

2両目以降にもLED順次表示を組み込む場合は、
まず表示させたい車輌に合わせたリソース画像を作成してください。
画像の作成については当サイトの車輌テクスチャーを参考にしてください。

E233系京浜東北線の場合、図のように複雑なLED表示のため、
前面LEDを装備した車輌と装備していない車輌で、
テクスチャーの作り方を分ける必要があります。

↓

前面LEDを装備した車輌の場合は、
図のように1つの行き先に対して合計10枚必要になります。
（停車中…6枚　低中速走行中…2枚　高速走行中…2枚）

前面LEDの2種類を交互表示させつつ、
側面LEDの3種類を順次表示させるために枚数が増えます。

↓

前面LEDを装備していない車輌の場合は、
図のように1つの行き先に対して合計6枚必要になります。
（停車中…3枚　低中速走行中…2枚　高速走行中…1枚）

前面LEDの表示を考える必要がないので、
側面LEDの各表示パターンを用意するだけです。

↓

リソース画像の準備が出来たら、
1両目の時と同様の方法で編成エディターに画像を追加してください。

ワンポイント

リソース画像は管理しやすいように
編成の何号車に表示させる画像なのかファイル名に含めておくと
後で追加・編集する際にわかりやすくなるのでオススメです。

↓

次にリソース画像を表示させる車両へスクリプトを記述します。
下記の車両スクリプトをコピーして貼り付けてください。
基本的には1両目に貼り付けたものと同じスクリプトです。

ただし、先ほど編成エディターに追加したリソース画像に合わせて、
青でハイライト表示した各行にある*の部分を
必ず下記に従って書き換えてください。

上記の場合だと、以下のように書き換えればOKです。
高速・初期開始IDの*は、21に書き換える。
高速・初期終了IDの*は、21に書き換える。
走行・初期開始IDの*は、22に書き換える。
走行・初期終了IDの*は、23に書き換える。
停車・初期開始IDの*は、24に書き換える。
停車・初期終了IDの*は、26に書き換える。
パターン数の*は、6に書き換える。
行き先数の*は、2に書き換える。

以上でLED交互表示の組み込みは完了です。
ビュワーを起動して、組み込んだ車輌のLED動作を確認してください。

▼ 車両スクリプト

										//---------------設定項目▼--
										Var 高速・初期開始ID
										set 高速・初期開始ID *
										Var 高速・初期終了ID
										set 高速・初期終了ID *

										Var 走行・初期開始ID
										set 走行・初期開始ID *
										Var 走行・初期終了ID
										set 走行・初期終了ID *

										Var 停車・初期開始ID
										set 停車・初期開始ID *
										Var 停車・初期終了ID
										set 停車・初期終了ID *

										Var パターン数
										set パターン数 *

										Var 行き先数
										set 行き先数 *

										Var 切替間隔
										set 切替間隔 3
										//---------------設定項目▲--

										//---------変数の初期設定▼--
										mul 切替間隔 1000

										Var 速度対応表示
										set 速度対応表示 0

										Var 変更回数
										set 変更回数 1

										Var 高速・開始ID
										mov 高速・開始ID 高速・初期開始ID

										Var 高速・終了ID
										mov 高速・終了ID 高速・初期終了ID

										Var 走行・開始ID
										mov 走行・開始ID 走行・初期開始ID

										Var 走行・終了ID
										mov 走行・終了ID 走行・初期終了ID

										Var 停車・開始ID
										mov 停車・開始ID 停車・初期開始ID

										Var 停車・終了ID
										mov 停車・終了ID 停車・初期終了ID

										Var 現行表示ID
										set 現行表示ID 高速・開始ID
										//---------変数の初期設定▲--

										//---タイマーイベント登録▼--
										Var 交互表示
										SetEventTimer this 方向幕制御 交互表示 切替間隔
										//---タイマーイベント登録▲--

										//---------各メソッド定義▼--
										BeginFunc 方向幕制御
										  Var TRN
										  getparent	TRN
										  call TRN 速度監視
										  add 現行表示ID 1

										 ifeq 速度対応表示 1
										  if> 現行表示ID 停車・終了ID
										   mov 現行表示ID 停車・開始ID
										  endif
										 endif

										 ifeq 速度対応表示 2
										  if> 現行表示ID 走行・終了ID
										   mov 現行表示ID 走行・開始ID
										  endif
										 endif

										 ifeq 速度対応表示 3
										  if> 現行表示ID 高速・終了ID
										   mov 現行表示ID 高速・開始ID
										  endif
										 endif

										 SetSignTexture 現行表示ID
										EndFunc

										BeginFunc 行き先変更
										 set 速度対応表示 0
										 add 変更回数 1

										 if> 変更回数 行き先数
										  set 変更回数 1
										  mov 高速・開始ID 高速・初期開始ID
										  mov 高速・終了ID 高速・初期終了ID

										  mov 走行・開始ID 走行・初期開始ID
										  mov 走行・終了ID 走行・初期終了ID

										  mov 停車・開始ID 停車・初期開始ID
										  mov 停車・終了ID 停車・初期終了ID
										 else
										  add 高速・開始ID パターン数
										  add 高速・終了ID パターン数

										  add 走行・開始ID パターン数
										  add 走行・終了ID パターン数

										  add 停車・開始ID パターン数
										  add 停車・終了ID パターン数
										 endif
										EndFunc

										BeginFunc 停車判定
										 ifeq 速度対応表示 1
										 else
										  mov 現行表示ID 停車・開始ID
										 endif
										 set 速度対応表示 1
										EndFunc

										BeginFunc 走行判定
										 ifeq 速度対応表示 2
										 else
										  mov 現行表示ID 走行・開始ID
										 endif
										 set 速度対応表示 2
										EndFunc

										BeginFunc 高速判定
										 ifeq 速度対応表示 3
										 else
										  mov 現行表示ID 高速・開始ID
										 endif
										 set 速度対応表示 3
										EndFunc
										//---------各メソッド定義▲--

▲ ページの一番上に戻ります